#脚本#bat批处理脚本,一键修改Windows远程桌面3389端口与用户密码

作者: MJJ 分类: 一键脚本 发布时间: 2019-04-13 14:45

不用软件麻烦,bat批处理脚本就能完成这两项任务,由于各位DD完Windows系统后,

修改远程端口比较麻烦,特此推出一键脚本,方便各位坛友。


@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
title 修改远程端口与用户密码  www.nat.ee
mode con: cols=55 lines=10
color 17
set "ing=ping -n 5 127.0.0.1 > nul"
:Menu
cls
echo ==============================
echo.
echo 1.修改远程端口
echo.
echo 2.修改用户密码
echo.
echo 3.重启计算机
echo.
echo ==============================
choice /C:123 /N /M "请输入你的选项 [1,2,3]":
if errorlevel 3 goto:Restart
if errorlevel 2 goto:Password
if errorlevel 1 goto:RemotePort
:RemotePort
cls
set /P "Port=自定义远程桌面端口(1-65535): "
if %Port% leq 65535 (
Reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\Wds\rdpwd\Tds\tcp" /v "PortNumber" /t REG_DWORD /d "%Port%" /f  > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v "PortNumber" /t REG_DWORD /d "%Port%" /f  > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\FirewallRules" /v "{338933891-3389-3389-3389-338933893389}" /t REG_SZ /d "v2.29|Action=Allow|Active=TRUE|Dir=In|Protocol=6|LPort=%Port%|Name=Remote Desktop(TCP-In)|" /f > nul
Reg add "HKLM\SYSTEM\CurrentControlSet\Services\SharedAccess\Parameters\FirewallPolicy\FirewallRules" /v "{338933892-3389-3389-3389-338933893389}" /t REG_SZ /d "v2.29|Action=Allow|Active=TRUE|Dir=In|Protocol=17|LPort=%Port%|Name=Remote Desktop(UDP-In)|" /f > nul
echo 修改成功
echo 请牢记,你的远程端口是: %Port% 
echo 重启计算机生效
%ing% && goto:Menu) else (echo 错误的端口,%Port% 大于所设置的范围,请在"1-65535"内。
%ing% && goto:RemotePort)
:Password
cls
echo 当前修改Administrator用户密码
set /p pwd1=请输入密码:
cls
set /p pwd2=请再次输入密码:
if "%pwd1%"=="%pwd2%" (
net user Administrator %pwd2% > nul
echo 修改成功,请牢记你的密码。
%ing% && goto:Menu)else (echo 密码错误,请重新输入。
%ing% && goto:Password)
:Restart
shutdown.exe /r /f /t 0

另存为 3389.bat 脚本即可。

有些不懂的坛友,这个是除了修改3389端口,还会添加修改的远程端口到防火墙中放行的。

放了一个无菜单版本的,一键执行修改,需要你预先在脚本里的 RemotePort 和 Password 参数中,填写自定义端口和密码。


下载

3389_0.4.zip (bat菜单脚本)

3389_NoInterface.zip (无菜单)

作者:老司机

查看原帖:https://www.hostloc.com/thread-538482-1-1.html

支持作者:www.nat.ee

发表评论

电子邮件地址不会被公开。 必填项已用*标注